# Maintainer:  Dave Murphy <davem@devkitpro.org>

pkgname=switch-sdl2
pkgver=2.0.8
pkgrel=16
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Nintendo Switch port)"
arch=('any')
url="https://libsdl.org"
license=("LGPL")
options=(!strip libtool staticlibs)
makedepends=('switch-pkg-config' 'devkitpro-pkgbuild-helpers')
depends=('switch-mesa' 'libnx')
source=("${url}/release/SDL2-${pkgver}.tar.gz" "SDL2-${pkgver}.patch")
groups=('switch-portlibs')
sha256sums=(
  'edc77c57308661d576e843344d8638e025a7818bff73f8fbfab09c3c5fd092ec'
  'd04f1be93ceb5fb1fa06c391aa81406f9756151b2de7b458218b8333abc07f75'
)

build() {
  cd SDL2-$pkgver

  source /opt/devkitpro/switchvars.sh

  patch -p1 -i $srcdir/SDL2-2.0.8.patch

  ./configure --prefix="${PORTLIBS_PREFIX}" --host=aarch64-none-elf \
  --disable-shared --enable-static \
  --enable-audio \
  --enable-joystick \
  --disable-power \
  --disable-cpuinfo \
  --disable-filesystem \
  --enable-threads \
  --enable-timers \
  --enable-video

  make
}

package() {
  cd SDL2-$pkgver

  source /opt/devkitpro/switchvars.sh

  make DESTDIR="$pkgdir" install

  # remove useless stuff
  rm -r "$pkgdir"${PORTLIBS_PREFIX}/share
}